home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 20 / Cream of the Crop 20 (Terry Blount) (1996).iso / bbs / maxfreq2.zip / REQPCESS.BAT < prev    next >
DOS Batch File  |  1996-06-11  |  2KB  |  59 lines
  1. @echo off
  2. rem
  3. rem    This file extracts a file's extension, then calls \MAX\VIRCHECK.BAT.
  4. rem
  5. rem    Alternately, you can process files right from this batch file using
  6. rem    the supplied variables.
  7. rem
  8. rem        eg.  SCAN %1%2
  9. rem             TOUCH %1%2
  10. rem
  11. rem    IMPORTANT NOTE: If you have configured Maximus to send all uploads to
  12. rem    one directory, you may need to alter your VIRCHECK.BAT to allow file
  13. rem    processing in ANY file area.
  14. rem
  15. rem    If in doubt, comment out "call vircheck %1 %PRE% %EXT% %4:\MAX\MISC\"
  16. rem    (third last line) until you have time to experiment. :-)
  17. rem
  18. rem    The variables passed to this batch files are:
  19. rem
  20. rem    %1 Current file area with trailing backslash (%F)
  21. rem    %2 File name
  22. rem    %3 Current file area without trailing backslash (%Q)
  23. rem    %4 Current drive letter (%x)
  24. rem    %5 Current task number (%k)
  25. rem
  26. set cmd=%2+
  27. :loop
  28. set orig=%cmd%
  29. if "%cmd%"=="+" goto out
  30. for %%a in (/%orig%) do if "%%a"=="." goto ext
  31. for %%a in (/%cmd%) do set cmd=%%a
  32. for %%a in (/%orig%) do if %%a%cmd%==%orig% set pre=%pre%%%a
  33. goto loop
  34. :ext
  35. set orig=%cmd%
  36. if "%cmd%"=="+" goto out
  37. for %%a in (/%orig%) do if "%%a"=="+" goto out
  38. for %%a in (/%cmd%) do set cmd=%%a
  39. for %%a in (/%orig%) do if %%a%cmd%==%orig% set ext=%ext%%%a
  40. goto ext
  41. :out
  42. for %%a in (/%cmd%) do set cmd=%%a
  43. for %%a in (/%orig%) do if %%a%cmd%==%orig% set ext=%ext%%%a
  44. set cmd=
  45. set orig=
  46. if (%ext%)==() GOTO NOext
  47. if %ext%==.zip set ext=.ZIP
  48. if %ext%==.arj set ext=.ARJ
  49. if %ext%==.zoo set ext=.ZOO
  50. if %ext%==.lzh set ext=.LZH
  51. if %ext%==.pak set ext=.PAK
  52. if %ext%==.arc set ext=.ARC
  53. if %ext%==.lha set ext=.LHA
  54. if %ext%==.rar set ext=.RAR
  55. :noext
  56. call vircheck %1 %PRE% %EXT% MISC\
  57. set pre=
  58. set ext=
  59.